feat: Add highlights support for hcl

Signed-off-by: Xuanwo <github@xuanwo.io>

sample_files/compare.expected

@@ -41,7 +41,7 @@ sample_files/haskell_before.hs sample_files/haskell_after.hs
 9c668c79e56f1e1cecf1c02759c195a9  -
 
 sample_files/hcl_before.hcl sample_files/hcl_after.hcl
-bbd894db56c616c18bbe3afb23f1a72b  -
+5918eacc75d3277c1f64df1116ec356d  -
 
 sample_files/helpful_before.el sample_files/helpful_after.el
 bce74573e003cc6b729a63a4bc34c4af  -

src/tree_sitter_parser.rs

@@ -322,7 +322,11 @@ pub fn from_language(language: guess::Language) -> TreeSitterConfig {
                     ("%{~", "~}"),
                     ("${", "}"),
                 ],
-                highlight_query: ts::Query::new(language, "").unwrap(),
+                highlight_query: ts::Query::new(
+                    language,
+                    include_str!("../vendor/highlights/hcl.scm"),
+                )
+                .unwrap(),
             }
         }
         Janet => {

vendor/highlights/hcl.scm

@@ -0,0 +1,103 @@
+;; Based on the nvim-treesitter highlighting, which is under the  Apache license.
+;; See https://github.com/nvim-treesitter/nvim-treesitter/blob/09ad32c91bbc6a2813c1293d2373c6604e0f6ea4/queries/hcl/highlights.scm
+
+[
+  "!"
+  "\*"
+  "/"
+  "%"
+  "\+"
+  "-"
+  ">"
+  ">="
+  "<"
+  "<="
+  "=="
+  "!="
+  "&&"
+  "||"
+] @operator
+
+[
+  "{"
+  "}"
+  "["
+  "]"
+  "("
+  ")"
+] @punctuation.bracket
+
+[
+  "."
+  ".*"
+  ","
+  "[*]"
+] @punctuation.delimiter
+
+[
+  (ellipsis)
+  "\?"
+  "=>"
+] @punctuation.special
+
+[
+  ":"
+  "="
+] @none
+
+[
+  "for"
+  "endfor"
+  "in"
+] @repeat
+
+[
+  "if"
+  "else"
+  "endif"
+] @conditional
+
+[
+  (quoted_template_start) ; "
+  (quoted_template_end); "
+  (template_literal) ; non-interpolation/directive content
+] @string
+
+[
+  (heredoc_identifier) ; <<END
+  (heredoc_start) ; END
+] @punctuation.delimiter
+
+[
+  (template_interpolation_start) ; ${
+  (template_interpolation_end) ; }
+  (template_directive_start) ; %{
+  (template_directive_end) ; }
+  (strip_marker) ; ~
+] @punctuation.special
+
+(numeric_lit) @number
+(bool_lit) @boolean
+(null_lit) @constant
+(comment) @comment
+(identifier) @variable
+
+(block (identifier) @type)
+(function_call (identifier) @function)
+(attribute (identifier) @field)
+
+; { key: val }
+;
+; highlight identifier keys as though they were block attributes
+(object_elem key: (expression (variable_expr (identifier) @field)))
+
+((identifier) @keyword (#any-of? @keyword "module" "root" "cwd" "resource" "variable" "data" "locals" "terraform" "provider" "output"))
+((identifier) @type.builtin (#any-of? @type.builtin "bool" "string" "number" "object" "tuple" "list" "map" "set" "any"))
+(variable_expr (identifier) @variable.builtin (#any-of? @variable.builtin "var" "local" "path"))
+(get_attr (identifier) @variable.builtin (#any-of? @variable.builtin  "root" "cwd" "module"))
+
+(object_elem val: (expression
+  (variable_expr
+    (identifier) @type.builtin (#any-of? @type.builtin "bool" "string" "number" "object" "tuple" "list" "map" "set" "any"))))
+
+(ERROR) @error